perm filename MTCSER[KA,SYS] blob sn#214693 filedate 1976-05-12 generic text, type C, neo UTF8
COMMENT ⊗   VALID 00012 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00003 00002	BEGIN	MTCSER ↔ SUBTTL	MTCSER - MAGNETIC TAPE ROUTINES FOR PDP-6(516)
C00010 00003	MTCDSP - DISPATCH TABLE, MTCREL - RELEASE UUO
C00012 00004	MTCLOK, MTCLK, REWCK, MTREWW
C00017 00005	DETMDC, DETDC, MTCHEK, MTCHK2
C00022 00006	MTAPEU, MTAPE, MTAPE2, MTXCT, MTGO1
C00029 00007	BUFFERED IO
C00036 00008	CLOSE OUTPUT, MTCINI, MTHUNG,
C00038 00009	MTDCN1 - BLK COUNTED OUT (HERE IN CHANNEL 1)
C00040 00010	LOW PRIORITY (CH4) INTERRUPTS FROM MTC COME HERE
C00043 00011	MTEOR - HERE ON ERF INTERRUPT FROM DATA TRANSFER OPERATION
C00053 00012	DUMP MODE IO
C00058 ENDMK
C⊗;
BEGIN	MTCSER ↔ SUBTTL	MTCSER - MAGNETIC TAPE ROUTINES FOR PDP-6(516)
;	25-JUL-68 FROM DEC MTCSR6 OF 7-MAY-68

Comment % The hardware

MTC CONO BITS:
Function codes are:
	00=NO OPERATION 
	01=REWIND
	02=WRITE
	03=WRITE END-OF-FILE
	04=READ-COMPARE (NOT USED)
	05=READ
	06=SPACE FORWARD RECORD
	07=BACKSPACE RECORD
	10=NO OPERATION (NOT USED)
	11=REWIND AND UNLOAD (SAME AS REWIND AT STANFORD)
	12=READ ACROSS RECORD (NOT USED)
	13=WRITE THREE INCHES (APPROX) OF MAG TAPE
	14=WRITE WITH LONG EOR (NOT USED)
	15=READ BACKWARD (NOT USED)
	16=SPACE FORWARD FILE
	17=BACKSPACE FILE

Density Codes are:
	0=200 BPI
	1=556 BPI
	2=800 BPI
	3=556 BPI

Parity:
	0=EVEN
	1=ODD

Slice level:
	0=HIGH (NORMAL)
	1=LOW

Magtape Control information.
Stanford 516 Magtape Controller, 521 interface, 570 Magtape drives

Device 220	MTC
Bit	CONO		CONI
18	unused		RD FER		False end of record
19	unused		WT EWC		Write Clock Enable
20	Slice level
21	Parity
22	density
23	density
24	function-8
25	function-4
26	function-2
27	function-1
28	pool 				Hold (don't pool) after completion
29	unit-4				Software Unit number comes from PUNIT
30	unit-2
31	unit-1
32	EOR 1 disable			maintenance only
33	PIA-4
34	PIA-2
35	PIA-1

Device 224	MTS
Bit	CONO 		CONI
18	INT CLR		CS ILC		Initial-Clear / Illegal command
19	unused		MD DCS		Motion Stop delay in progress
20	LIE		MD LIF		Load point interrupt Enable/Bit
21	XNE		CS XNC		Transfer next command Enable/Bit
22			T Rewinding
23			T End Point
24			T Load Point
25			TLR Last	Last operation was a Write
26			TFR A/B work	Local ∨ other controller is using this unit
27			EFF		End of File Flag
28			T Write Lock
29			RD MIS		Missed character
30			RD RCE		Read compare error
31			RD LPE		Long. Parity Error
32			PER		Lat. Parity Error
33	EFE		MD ERF		End of Record Flag Enable/Bit
34	Prog JNU	ST Ready	Tape Unit Ready
35	ICE		MD ICR		Interface & Control Enable/Ready

Device 230	MTM
Note: All CONO bit are ignored, however the CONO itself causes a programmed
CHP pulse to occur.

Bit			CONI
18			CS UPS		Up to speed
19			CS RIP		Record in Progress
20			CS ERM		End of record motion delay in progress
21			CS CON		Motion Continue Selected
22			CS CHF		Command Hold buffer Full
23			CS UNS		Unit selected new command
24			CM Function-8	Final function register
25			CM Function-4
26			CM Function-2
27			CM Function-1
28			CM Unit-4	Final Unit register
29			CM Unit-2
30			CM Unit-1
31			MD MOD		
32			RD FCD
33			RD ERD		Read End of Record delay
34			RD MCD
35			WT EWD		End of record Write delay

%


MTDC←←2		;MAG TAPE DATA CONTROL DEVICE NUMBER
SEL←←2		;UNIT TO COMMAND BUFFER (CALLED "PROGRAMMED JNU" IN H-516)

IOSEOF←←  4000	;SPACING ONE RECORD FORWARD FOUND EOF
IODT←←   10000	;SET FOR A DATA TRANSFER TYPE COMMAND (JOB HAS DC)
IOSLIC←← 20000	;A 1 IF SLICE LEVEL IS 1, OTHERWISE 0.
HASMT←←  40000	;SET FOR THIS JOB HAS THE MAG TAPE CONTROL
ERSLIC←←100000	;SET WHEN IOSLIC IS SET DUE TO READ-ERROR RECOVERY ATTEMPT.
IOREW←← 400000	;SIGN BIT.  SET WHILE OPERATION IS PENDING THE FINISH OF REWIND


MTREDO←←=10	;NUMBER OF TIMES TO RETRY ON ERRORS

SLICE←←40	;SET SLICE LEVEL FROM SLEVEL - BIT IN MTAPE
SLEVEL←←20	;SET SLICE LEVEL TO THIS VALUE IF SLICE IS SET. - BIT IN MTAPE

;STATUS BITS IN MTS.  * MEANS CAUSES INTERRUPT WHEN ENABLED.
;NAMES ARE TAKEN FROM "MAGNETIC TAPE CONTROL 516 INSTRUCTION MANUAL" H-516

ICR←←1B35	;* INTERFACE AND CONTROL READY
RDY←←1B34	;  TAPE TRANSPORT READY
ERF←←1B33	;* END OF RECORD FLAG
PER←←1B32	;  LATERAL PARITY ERROR
LPE←←1B31	;  LONGITUDINAL PARITY ERROR
RCE←←1B30	;  READ COMPARE ERROR (NOT USED)
MIS←←1B29	;  TAPE MISSED CHARACTER
TWL←←1B28	;  TAPE WRITE-ENABLE LOCKOUT RING OUT
EFF←←1B27	;  END-OF-FILE SENSED
BCT←←1B26	;  OTHER COMPUTER USING TRANSPORT OR IN LOCAL
TLR←←1B25	;  LAST OPERATION WAS A WRITE (NOT USED)
TLP←←1B24	;  TAPE AT LOAD POINT
TEP←←1B23	;  TAPE AT END POINT
RWD←←1B22	;  TRANSPORT IS REWINDING
XNC←←1B21	;* TRANSFER NEW COMMAND
LIF←←1B20	;* LOAD POINT INTERRUPT FLAG (NOT USED)
DCS←←1B19	;  DATA CONTROL SELECTED (NOT USED)
ILC←←1B18	;  ILLEGAL COMMAND:
		;     WRITE OR WEF ON A WRITE-LOCKED TAPE
		;     BACKSPACE RECORD, BACKSPACE FILE, OR READ
		;	BACKWARDS WHILE AT BEGINNING OF TAPE
		;     ANY OPERATION ON A TRANSPORT BEING USED
		;	BY THE OTHER COMPUTER

;MTCDSP - DISPATCH TABLE, MTCREL - RELEASE UUO

	JRST	MTCINI		;INITIALIZATION
	JRST	MTHUNG		;HUNG TIMEOUT.  RELEASE DC, MTC, PRINT ERROR.
↑MTCDSP:JRST	MTCREL		;RELEASE
	JRST	MTCLSO		;CLOSE OUTPUT
	JRST	MTOUT		;OUTPUT
	JRST	MTIN		;INPUT
	JRST	CPOPJ1		;ENTER IN DIRECTORY
	JRST	CPOPJ1		;LOOKUP IN DIRECTORY
	JRST	MTDMPO		;DUMP OUTPUT
	JRST	MTDMPI		;DUMP INPUT
	POPJ	P,		;SETO
	POPJ	P,		;SETI
	POPJ	P,		;GETF
	JRST	CPOPJ1		;RENAME
	POPJ	P,		;CLOSE INPUT
	POPJ	P,		;UTPCLR
	JRST	MTAPEU		;MTAPE UUO

MTCREL:	PUSHJ	P,WAIT1		;WAIT FOR IOACT TO BE OFF.
	MOVE	IOS,[ERSLIC!IOSLIC,,-1]
	ANDCAB	IOS,DEVIOS(DDB)	;FLUSH LOTS OF BITS
	POPJ	P,
;MTCLOK, MTCLK, REWCK, MTREWW

;COUNT THE NUMBER OF UNITS THAT ARE WAITING FOR REWIND

MTREWW:	SETOM	MTREWN		;SET COUNT TO NO. UNITS IN REW WAIT
	PUSH	P,DDB
	MOVEI	DDB,MTCDDB	;GET BEGINNING OF MT DATA BLOCK CHAIN
REWLP:	MOVE	IOS,DEVIOS(DDB)
	JUMPGE	IOS,REW2	;IS UNIT IN A REW WAIT?
	PUSHJ	P,REWCK		;YES,SEE IF FINISHED REW.
	JRST	.+3		;HAS FINISHED REWINDING
	JRST	.+2		;OFF.  WAKE HIM UP TO MAKE HIM LOSE.
	JRST	REW0		;STILL REWINDING 
	TLZ	IOS,IOREW	;NO LONGER IN REWIND WAIT.
	TLZE	IOS,IOW		;SKIP UNLESS WE NEED TO WAKE HIM UP
	PUSHJ	P,SETIOD	;START JOB UP AGAIN
	MOVEM	IOS,DEVIOS(DDB)
	JRST	REW2

REW0:	AOS	MTREWN		;INCREMENT COUNT OF REW WAIT UNITS
REW2:	HLRZ	DDB,DEVSER(DDB)	;LINK TO NEXT DDB
	JUMPE	DDB,REW3	;LAST DDB?
	HRRZ	DAT,DEVSER(DDB)	;NO. GET DEVICE SERVICE ROUTINE ADDRESS
	CAIN	DAT,MTCDSP	;IS THIS A MAGTAPE?
	JRST	REWLP		;YES. CONTINUE
REW3:	POP	P,DDB
	POPJ	P,		;YES, DISMISS INTERRUPT OR RETURN TO MTCLOK

;HERE AT CLOCK LEVEL TO SEE IF ANY UNITS IN A REWIND WAIT HAVE FINISHED REWIND

MTCLOK:	SKIPGE	MTREQ		;IS MTC FREE?
	PUSHJ	P,MTREWW	;YES.  CHECK ALL MAG TAPE UNITS TO SEE IF ANY THAT
				;WERE IN REWIND WAIT HAVE FINISHED REWINING.
	SKIPGE	MTREWN		;ARE ANY UNITS STILL IN REWIND WAIT?
	POPJ	P,		;NO, EXIT WITHOUT REPLANTING CLOCK REQUEST.
MTCLK:	MOVE	TAC1,[MTCLOK,,JIFSEC/2]		;COME BACK IN HALF A SECOND
	CONO	PI,PIOFF
	IDPB	TAC1,CLOCK(PID)
	CONO	PI,PION
	POPJ	P,


;REWCK- CHECK IF UNIT IS REWINDING.
;CALL	MOVE DDB,ADDRESS OF DDB
;	PUSHJ P,REWCK
;	UNIT READY
;	UNIT OFF
;	UNIT REWINDING

;THIS CODE REQUIRES THAT A) NO TAPES ARE CURRENTLY IN USE.
;			 B) THE TAPE CONTROL BELONGS TO THE TAPE YOU'RE QUERYING


REWCK:	LDB	TAC,PUNIT	;GET UNIT NUMBER
	ROT	TAC,4		;MOVE TO CORRECT POSITION
	CONO	MTC,MTCCHN(TAC)	;CONO A NOOP, UNIT, CORRECT PIA.
	CONO	MTS,SEL		;JAM UNIT INTO COMMAND BUFFER ("PROGRAMMED JNU")
	CONSZ	MTS,RWD		;SKIP IF REWIND MOTION OFF
	JRST	CPOPJ2		;RETURN TO CALL+2 IF TAPE REWINDING
	CONSO	MTS,BCT		;OTHER COMPUTER USING TRANSPORT, OR IN LOCAL?
	CONSO	MTS,RDY		;IS UNIT READY?
	JRST	CPOPJ1		;UNIT UNREADY OR UNAVAILABLE
	CONSZ	MTS,TLP		;UNIT READY AND AVAILABLE IS IT AT LOAD POINT?
	IORI	IOS,IOBOT	;YES.
	CONSZ	MTS,TEP		;END POINT?
	IORI	IOS,IOTEND	;YES.
	POPJ	P,		;UNIT HAPPY. DIRECT RETURN


COMMENT $
THIS WORKS WITH THE FOLLOWING MOD TO 545 TRANSPORT:

DELETE 1B23K TO ??

ADD	1B16K TO 1B08K		REW(1)(GND) BUFFERED
	1B19S TO 1B08L		FWD/LP(1)(GND)
	1B08N TO 1B23K		(REW(1).OR.FWD/LP(1))

THIS MOD SETS IOB22(1) WHILE MAGTAPE IS REWINDING OR SPACING FORWARD
TO LOAD POINT- IE ENABLES THE PROCESSOR TO DISTINGUISH BETWEEN A
TAPE WHICH IS AT THE END OF A REWIND COMMAND, AND A TAPE WHICH IS
SWITCHED TO LOCAL, OR OFF

ADD	1B08U TO 1B08N		CLAMPED LOAD FOR LOCAL
	1B08R TO 1B10J		LOCAL (-3V)
	1B08S TO 1B15F		SELECT (-3V)
	1B08V TO P1-42		LOCAL STATUS TO OLD POOL STATUS BIT
	P1-42 TO P2-42		ADD THROUGH CONNECTION FOR DRIVES BEYOND

THIS MOD MAKES BIT 26 OF CONI 224,  A ONE IF THE SELECTED
DRIVE IS IN LOCAL.  IT USES A SPARE SECTION OF R111 IN EACH 545
AND LOGIC IN THE 516/521 USED FOR POOLING WITH 570 TAPE DRIVES.
$
;DETMDC, DETDC, MTCHEK, MTCHK2

;DETMDC - TURN OFF HASMT.  IF HASMT WAS ON, DETACH MTC, AND CALL DETDC
;DETDC -  TURN OFF IODT, IF IODT WAS ON THEN DETACH DC.

DETMDC:	TLZN	IOS,HASMT	;THIS JOB HAS MTC?
	JRST	STOIOS		;NO (IT DOESN'T HAVE DC EITHER!)
	SETZM	MTCUSR		;FLAG THERE IS NO ONE USING MT CONTROL
	SOSL	MTREQ		;IS THERE ANYONE ELSE WAITING FOR IT?
	SETOM	MTAVAL		;YES.  FLAG TO INDICATE IT IS NOW AVAILABLE.

IFN FTEXPG,<	SETZM	EXPGT+MTCEXP	;GIVE BACK ANY EXEC PAGES.
		SETZM	EXPGT+MTCEXP+1
NOKL10,<	CONO	PAG,1		>;NOKL10
IFKL10,<	CONO	KLPAG,@KLPCON	>;IFKL10
					>;IFN FTEXPG

DETDC:	TLZN	IOS,IODT	;DOES JOB HAVE DATA CONTROL?
	JRST	STOIOS		;NO.
	SOSL	DCREQ		;ANYONE ELSE WAITING FOR IT?
	SETOM	DCAVAL		;YES.  FLAG AS JUST BECOME AVAILABLE.
	JRST	STOIOS

;GET CONTROL OF MTC AND DC.  MAKE SURE TAPE IS READY
MTCXX1:	PUSHJ	P,MTCXXX	;BUG TRAP!
MTCHEK:	PUSHJ	P,GETDCMT	;GET DATA AND MAG TAPE CONTROLS
	 AOSE	 MTREQ		;ARGUMENT
	SKIPE	MTCUSR		;SKIP IF THERE REALLY IS NOONE USING MTC
	JRST	MTCXX1		;BUG TRAP
	PUSH	P,JOB(PID)
	POP	P,MTCUSR
	MOVE	IOS,DEVIOS(DDB)
	TLO	IOS,IODT	;FLAG DATA TRANSFER
	PUSHJ	P,MTCHK4	;WAIT FOR REWIND
	JRST	MTCHEK		;GET DC & MT AGAIN
	JRST	SETACT		;SET DEV. ACTIVE BIT

MTCXXX:	CONO	PI,PIOFF
	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/RETURNED FROM GETDCMT OR MTWAIT WITH MTCUSR NON-ZERO.
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,WDDTCALL
	CONO	PI,PION
	SOSL	MTREQ
	SETOM	MTAVAL
	POPJ	P,

MTCYYY:	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/AT MTCHK4 WITH HASMT ALREADY SET IN DEVIOS.
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,DDTCALL
	POPJ	P,

;GET CONTROL OF MTC ONLY.  MAKE SURE TAPE IS READY.
MTCXX2:	PUSHJ	P,MTCXXX
MTCHK2:	AOSE	MTREQ		;(THIS IS ALSO ARGUMENT TO MTWAIT)
	PUSHJ	P,MTWAIT
	SKIPE	MTCUSR
	JRST	MTCXX2
	PUSH	P,JOB(PID)
	POP	P,MTCUSR
	MOVE	IOS,DEVIOS(DDB)
	PUSHJ	P,MTCHK4	;CHECK STATUS
	JRST	MTCHK2		;STATUS LOST.  GET MT AGAIN.
	POPJ	P,

MTCHK4:	TLOE	IOS,HASMT	;THIS JOB NOW HAS MTC
	PUSHJ	P,MTCYYY	;BUGTRAP.
	TLZE	IOS,IOBEG	;FIRST OPERATION AFTER INIT 
	TLZ	IOS,IOSLIC	;YES, SET SLICE LEVEL TO 0.
	TLZ	IOS,IOREW	;CLEAR MAG TAPE REWINDING
	PUSHJ	P,REWCK		;CHECK IF REWINDING?
	JRST	CPOPJ1		;NO - STATUS OK
	JRST	QSTAT		;QUERY STATUS
	PUSHJ	P,DETMDC	;REWINDING- DETACH MTC, DC AND TURN OFF IODT & HASMT
	TLO	IOS,IOREW+IOW	;SET REWIND WAIT, IO WAIT
	MOVEM	IOS,DEVIOS(DDB)	;STORE IOS
	AOSG	MTREWN		;ADD 1 TO REWIND WAIT COUNT SKIP IF CLREQ IN
	PUSHJ	P,MTCLK		;MAKE A CLOCK REQUEST. THIS IS ONLY UNIT REWINDING
	PUSH	P,J		;SAVE J
	LDB	J,PJOBN		;GET THE JOB NUMBER OF TAPE OWNER
	MOVNI	AC1,IOWQ	;REQUE THIS GUY
	MOVEM	AC1,JOBQUE(J)	;TO IOWQ UNTIL MT REWINDS
	PUSHJ	P,REQUE		;
	POP	P,J		;RESTORE J
	JRST	WSCHED		;WAIT...

QSTAT:	PUSHJ	P,DETMDC	;DETACH MTC AND DC
	PUSH	P,J
	LDB	J,PJOBN		;LOAD UP JOB NUMBER
	PUSHJ	P,HNGSTP	;CHECK STATUS (PULL FINGERS OUT, ETC)
	POP	P,J
	POPJ	P,
;MTAPEU, MTAPE, MTAPE2, MTXCT, MTGO1

;THE FOLLOWING MTAPES ARE LEGAL:
C←←0
C←←C!1B35	;0 = NO-OP.  WAITS FOR THE CONTROL TO BE FREE, RELEASES IT AND
		;	RETURNS TO THE USER.  THIS PROVIDES THE ONLY WAY FOR A
		;	USER TO WAIT FOR A SPACING OPERATION TO COMPLETE.
		;	(SKIP, BACKSPACE, OR REWIND)
C←←C!1B34	;1 = REWIND
C←←C!1B26	;11= REWIND, UNLOAD
C←←C!1B28	;7 = BACKSPACE RECORD
C←←C!1B20	;17= BACKSPACE FILE
C←←C!1B32	;3 = WRITE END OF FILE
C←←C!1B29	;6 = SPACE FORWARD RECORD
C←←C!1B21	;16= SPACE FORWARD FILE
C←←C!1B24	;13= WRITE 3" OF BLANK TAPE
C←←C!1B27	;10= SKIP TO LOGICAL EOT (PROGRAMMED - SEE MTLEOT)

MTAPEU:	MOVEI	ITEM,1		;CHECK FOR LEGAL MTAPE UUO
	MOVEI	TAC,(UUO)	;GET FUNCTION CODE FROM USER'S UUO
	LSH	ITEM,(TAC)	;SHIFT BIT ACCORDING TO THE USER'S UUO
	CAIG	TAC,17		;SKIP IF FUNCTION CODE OUT OF BOUNDS.
	TRNN	ITEM,C		;DID HE SPECIFY A LEGAL CODE ?
	JRST	UUOERR		;NO--TYPE MONITOR ERROR MESSAGE.
	PUSHJ	P,MTCHK2	;MAKE SURE SYSTEM IS AVAILABLE. (ITEM IS PRESERVED)
	SOJE	ITEM,DETMDC	;FOR MTAPE 0 (SYNC WAIT), RELEASE DC&MT THEN RETURN
	TRZ	IOS,776000	;CLEAR ERROR BITS: IOF, IOACT, IOBOT AND IOTEND.
	SKIPA	ITEM,UUO	;CALL MTAPE2
MTAPE:	PUSHJ	P,MTCHK2	;CHECK IF MAG TAPE CONTROL AVAIL.
MTAPE2:	TDZ	IOS,[IODT!IOSEOF,,IOACT]	;THIS IS NOT A DATA TRANSFER OP.
	TRNN	ITEM,SLICE	;SET SLICE LEVEL THIS UUO?
	JRST	NOSET		;NO
	TLZ	IOS,IOSLIC	;YES, CLEAR LEVEL
	TRNE	ITEM,SLEVEL	;SET TO 1?
	TLO	IOS,IOSLIC	;YES
NOSET:	LSH	ITEM,=8		;MOVE CODE TO MT FUNCTION POSITION
	ANDI	ITEM,17B27	;LEAVE ONLY THE FUNCTION BITS
	CAIN	ITEM,10B27	;LOGICAL EOT?
	JRST	MTLEOT		;YES. - THIS FUNCTION IS DONE BY PROGRAM
	CONSO	MTS,TLP		;AT LOAD POINT?
	JRST	MTGO1		;NOT AT LOAD POINT.
	CAIE	ITEM,7B27	;YES, BACKSPACE RECORD?
	CAIN	ITEM,1B27	;NO, REW?
	JRST	MTFIN		;AVOID BACKWARDS MOTION WHEN AT LOAD POINT
	CAIN	ITEM,17B27	;NO. BACKSPACE FILE?
	JRST	MTFIN		;YES. AVOID BACKWARDS MOTION FROM LOAD POINT.
MTGO1:	LDB	TAC,PUNIT	;HERE FOR IO UUOS, AND INTERRUPT FOR NEXT RECORD
	DPB	TAC,[POINT 3,ITEM,31]	;FROM COMMAND IN ITEM. STORE UNIT NUMBER.
	LDB	TAC,[POINT 3,IOS,28]	;DENSITY PARITY
	TRNN	TAC,7		;NO DENSITY OR PARITY SPECIFIED?
	IORI	TAC,STDENS	;YES, USE STANDARD
	XORI	TAC,5		;ODD, 556
	DPB	TAC,[POINT 3,ITEM,23]
	MOVEI	TAC,MTCCHN(ITEM);ADD PI CHANNEL TO COMMAND
	TLNE	IOS,IOSLIC	;SLICE LEVEL A 1?
	TRO	TAC,100000	;YES, SET COMMAND.
	SETZM	MTEOFF		;CLEAR EOF FLAG
	HRRM	DDB,MTDEV
	HRLM	TAC,MTDEV	;COMMAND,,DDB ADDRESS INTO MTDEV
	MOVEI	TAC1,MTNIO2	;ASSUME NON-DATA TRANSFER
	TLNN	IOS,IODT	;IS THIS A DATA TRANSFER OPERATION  REQUIRING DC?
	JRST	MTGO2		;NO, MUST BE SPACING OPERATION
	CONO	DC,@MDCSAV	;YES, ATTACH DC TO MAGTAPE
	CONO	PI,DCTON	;TURN DC PI CHANNEL ON
	SETZM	MISSED		;CLEAR DATA MISSED FLAG
	MOVEI	TAC1,MTXNC	;ON INTERRUPT, GO TO MTXNC
MTGO2:	PUSH	P,TAC1		;SAVE DISPATCH ADDRESS
	PUSH	P,TAC
	PUSHJ	P,STOIOS	;STORE IOS.  INITIALIZE HUNG COUNT
	POP	P,TAC		;FALL INTO MTXCT
;HERE TO INITIATE THE EXECUTION OF AN MTAPE FOR THE ERROR ROUTINES.
;CALLED FROM I-LEVEL, WITH INTERFACE & CONTROL READY
MTXCT:	POP	P,MTIDSP	;STORE RETURN ADDRESS
	MOVEI	TAC1,XNC	;RETURN ON XNC
	CONO	PI,PIOFF
	CONO	MTC,(TAC)	;ISSUE THE OPERATION
	CONO	MTS,XNC		;ENABLE THE HARDWARE
	HRRM	TAC1,MTCCON	;AND THE SOFTWARE
	CONO	PI,PION		;ALLOW INTERRUPTS AGAIN
	POPJ	P,		;RETURN TO UUOCON OR DISMISS INTERRUPT

;LOGICAL END OF TAPE LOOP - IMPLEMENTS  MTAPE 10
;POSITIONS THE TAPE BETWEEN THE TWO EOFS THAT MARK THE EOT.
;THIS CODE IS EXECUTED AT UUO LEVEL

MTLEOT:	MOVEI	ITEM,7		;BACKSPACE
	PUSHJ	P,MTAPE2	;START COMMAND
	PUSHJ	P,MTCHK2	;WAIT FOR COMMAND TO FINISH BY CALLING INTERLOCK.
				;PICKUP IOS WHEN PREVIOUS TASK FINISHES.
MTEOT2:	MOVEI	ITEM,16		;SPACE ONE FILE
	PUSHJ	P,MTAPE2	;START IT
	MOVEI	ITEM,6		;SPACE ONE RECORD
	PUSHJ	P,MTAPE		;WAIT FOR SPACE FILE THEN START SPACE RECORD
	PUSHJ	P,MTCHK2	;WAIT FOR SPACE RECORD BY CALLING INTERLOCK
				;RETURN WHEN SPACING DONE WITH NEW IOS
	TLNN	IOS,IOSEOF	;WAS EOF DETECTED?
	JRST	MTEOT2		;NO, RESUME SPACING.
	MOVEI	ITEM,7		;PREPARE FOR BACKSPACE MTAPE
	JRST	MTAPE2		;BACKSPACE, LOGICAL EOT FOUND RETURN TO CALLER
;BUFFERED IO

MTIN:	PUSHJ	P,MTCHEK		;INPUT UUO.  IS SYSTEM AVAILABLE?
	TLZ	IOS,IO			;SET READING.
MTIN0:	MOVNI	TAC,MTREDO		;HERE AT I-LEVEL TO DO NEXT RECORD
	MOVEM	TAC,MTERCN
	TLZE	IOS,ERSLIC		;CLEAR SLICE LEVEL SET VIA ERROR RECOVERY
	TLC	IOS,IOSLIC		;IF ERSLIC WAS SET, COMPLEMENT IOSLIC
MTIN1:	HRRZ	TAC,DEVIAD(DDB)		;(RETRY FAILED RECORD) GET BUFFER ADDRESS
	XCTR	XR,[SETCM TAC,(TAC)]	;-(SIZE+1)-1 IN LEFT HALF.
	HRR	TAC,DEVIAD(DDB)		;-SIZE-2,,DATA BUFFER RELATIVE ADDRESS-2
	ADD	TAC,[2,,1]		;-SIZE,,RELATIVE DATA ADDRESS-1 = IOWD
MDRT1:	MOVEI	ITEM,5B27		;READ COMMAND
	MOVE	TAC1,[BLKI DC,4000!<MTDC*10>!DCTCHN]	;BLKI,,DC INITIAL CONO
;ALL I/O OPS COME THROUGH HERE TO BE STARTED (OR RETRIED)
MTINDC:	CONO	PI,DCTOFF		;TURN DATA CONTROL PI CHANNEL OFF
	MOVEM	TAC,DCWRD		;STORE BLKI/O POINTER
	HRRZM	TAC1,MDCSAV		;SAVE DC COMMAND (INITIAL CONO BITS)
	HRRI	TAC1,DCWRD		;SET UP ADDRESS PART OF BLKI/O INSTR.
	MOVEM	TAC1,@DCLOC		;STORE BLKI/O INSTRUCTION
	MOVE	TAC1,[JSR MTDCND]
	MOVEM	TAC1,@DCLOC1		;STORE BLKI/O OVERFLOW INSTR.
	HLRO	AC3,DCWRD		;GET -WC
	HRRZ	TAC1,DCWRD		;GET FIRST ADDRESS-1
	MOVEI	AC1,MTBLK		;ADDRESS TO STUFF PARTIAL IOWDS
	MOVEM	AC1,MTBLKP		;INITIAL POINTER TO IOWD LIST
MTINDD:	MOVEI	TEM,777
	ANDI	TEM,(TAC1)
	CAIN	TEM,777
	MOVNI	TEM,1
	SUBI	TEM,1777		;-(NUMBER OF WORDS BEFORE END OF 2ND PAGE)
	CAMGE	TEM,AC3			;IS MAX WC (TEM) LARGER THAN REMAINING WC?
	MOVE	TEM,AC3			;YES, REDUCE IT (THIS IS THE LAST ONE)
	HRLZM	TEM,(AC1)		;STORE -WC.
	HRRM	TAC1,(AC1)		;STORE ADDRESS-1
	ADDI	AC1,1			;INCREMENT COMMAND LIST POINTER.
	CAIL	AC1,MTBLKP		;ARE WE STILL IN BOUNDS?
	JRST	MTDMP2			;LOSE - GIVE ADDRESS ERROR.
	SUB	AC3,TEM			;DECREMENT WC BY THE AMOUNT WE JUST NIBBLED
	SUB	TAC1,TEM		;AND ADVANCE THE CORE ADDRESS BY THE SAME
	JUMPL	AC3,MTINDD		;LOOP UNLESS WE'RE DONE WITH THIS IOWD
	SETZM	(AC1)			;STORE A ZERO TO END THE LIST.


IFE FTEXPG,<	HRRZ	TAC,JBTPAG(J)
		LSH	TAC,=9
		MOVEM	TAC,MTPROG	;OLD WAY TO RELOCATE
		ADD	TAC,MTBLK	;THE OLD WAY TO RELOCATE!
		MOVEM	TAC,DCWRD	;STORE NEW IOWD
		HRRZM	TAC,MTDCCN	;STORE ABSOLUTE STARTING ADDRESS. >

IFN FTEXPG,<
	LDB	TAC1,PJOBN
	MOVE	TAC1,JBTMAP(TAC1)
	LSH	TAC1,=9
	MOVEM	TAC1,MTCMAP	
	MOVE	TAC,MTBLK
	ADDI	TAC,1			;FIRST CORE ADDRESS
	MOVEM	TAC,DCWRD		;SAVE BLKI/O POINTER+1
	LDB	TAC,[POINT 9,DCWRD,26]	;AC2←PAGE NUMBER OF FIRST WORD
	MOVEI	TAC1,MTCEXP		;NUMBER OF FIRST EXEC PAGE FOR MTC
	DPB	TAC1,[POINT 9,DCWRD,26]	;STORE EXEC PAGE NUMBER INSTEAD
	SOS	DCWRD			;RE-CONVERT TO IOWD FORMAT
	ADD	TAC,MTCMAP		;POINTER TO USER'S PAGE MAP ENTRY
	MOVE	TAC1,(TAC)
	MOVEM	TAC1,EXPGT+MTCEXP	;MAKE EXEC MAP POINT TO USER'S PAGES
	MOVE	TAC1,1(TAC)
	MOVEM	TAC1,EXPGT+MTCEXP+1
NOKL10,<	CONO	PAG,1		>;NOKL10
IFKL10,<	CONO	KLPAG,@KLPCON	>;IFKL10
>;IFN FTEXPG

	IORI	IOS,IOACT		;SET IOACT
	JRST	MTGO1			;GO START OPERATION

MTOUT:	PUSHJ	P,MTCHEK		;OUTPUT UUO.  IS SYSTEM AVAILABLE
	TLO	IOS,IO			;SET WRITING.
	CONSZ	MTS,TWL			;IS FILE PROTECT RING IN?
	JRST	MTOUTE			;NO, ERROR CANT WRITE.
MTOUT0:	MOVNI	TAC,MTREDO		;HERE AT I-LEVEL TO DO NEXT RECORD
	MOVEM	TAC,MTERCN
	TLZE	IOS,ERSLIC		;CLEAR SLICE LEVEL SET VIA ERROR RECOVERY
	TLC	IOS,IOSLIC		;IF ERSLIC WAS SET, COMPLEMENT IOSLIC
MTOUT1:	HRRZ	TAC,DEVOAD(DDB)		;(RETRY FAILING RECORD) GET BUFFER ADDRESS
	XCTR	XR,[MOVN TAC1,1(TAC)]	;-WD COUNT
	JUMPE	TAC1,MTNOPO		;IF WC=0, DONT DO ANYTHING
	HRL	TAC,TAC1		;-WD CNT,BUFFER = -WC,,DATA ADDRESS-2
	ADDI	TAC,1			;-WC,,DATA ADDRESS-1 = IOWD
MDWT1:	MOVEI	ITEM,2B27		;WRITE COMMAND
	MOVE	TAC1,[BLKO DC,3400!<MTDC*10>!DCTCHN]	;BLKO,,DC INITIAL CONO
	JRST	MTINDC

MTNOPO:	PUSHJ	P,ADVBFE		;ADVANCE OVER THE EMPTY BUFFER
	JFCL				;IGNORE CONTINUE INDICATION
MTNOP1:	PUSHJ	P,ETCHK			;JUST IN CASE
	TLZE	IOS,IOW			;UNWAIT THE JOB
	PUSHJ	P,SETIOD
	PUSHJ	P,CLRACT
	JRST	DETMDC			;DETACH EVERYTHING AND RETURN

MTOUTE:	TRO	IOS,IOIMPM		;WRITE LOCK, DEVICE ERROR
	JRST	MTNOP1			;DETACH DC AND MTC. RETURN TO UUOCON
;CLOSE OUTPUT, MTCINI, MTHUNG,

;CLOSE
MTCLSO:	TLNN	DDB,OUTPB	;HAS AN OUTPUT BEEN DONE?
	POPJ	P,		;NO. DONT WRITE ON TAPE.
	LDB	TAC,PIOMOD	;DUMP MODE?
	CAIGE	TAC,DR
	PUSHJ	P,OUT		;BUFFERED MODE: OUTPUT LAST PARTIAL BUFFER
	PUSHJ	P,WSYNC		;WAIT FOR OUTPUT TO FINISH
	MOVEI	ITEM,3		;WRITE EOF
	PUSHJ	P,MTAPE
	MOVEI	ITEM,3		;WRITE EOF
	PUSHJ	P,MTAPE
	MOVEI	ITEM,7		;BSP
	PUSHJ	P,MTAPE
	LDB	J,PJOBN		;RESTORE J AS JOB NUMBER
	POPJ	P,


;SYSTEM INITIALIZATION
MTCINI:	SETOM	MTREWN		;SET CLOCK REQUEST COUNT TO -1

NOKL10,<	MOVEI	TAC,40+DCTCHN*2
		CONSZ	APR,MAOFF	;TRAP OFFSET?
		IORI	TAC,100		;YES, OFFSET ADDRESS  >;NOKL10

IFKL10,<	MOVEI	TAC,KLEPT+40+DCTCHN*2	>;IFKL10  ADDRESS FOR INTERRUPTS

	MOVEM	TAC,DCLOC
	ADDI	TAC,1
	MOVEM	TAC,DCLOC1
	SETZM	DEVIOS(DDB)	;A NICE WAY TO START.
	JRST	MTNIO1

;HUNG TIMEOUT
MTHUNG:	TLNN	IOS,HASMT
	POPJ	P,		;HOW DID WE GET HERE IF HE DIDN'T HAVE IT?
	CONO	PI,PIOFF
	CONO	MTS,400000	;FLUSH CURRENT COMMAND. STOP/INITIALIZE TAPE CONTROL
	HLLZS	MTCCON		;NO MORE INTERRUPTS
	CONO	PI,PION
	TLNN	IOS,IODT	;DOES HE HAVE THE DATA CONTROL?
	JRST	MTNIO0		;NO.  GO CLEAN UP THE STATE OF THINGS
	CONO	DC,0		;HOLD DATA CONTROL
	CONO	PI,DCTOFF	;SHUT OFF DC
	JRST	MTNIO0		;CLEAN UP STATES OF THINGS

;MTDCN1 - BLK COUNTED OUT (HERE IN CHANNEL 1)

↑MTDCN1:MOVEM	TAC,MTTAC	;SAVE TAC
	AOS	TAC,MTBLKP	;ADVANCE TO NEXT IOWD IN COMMAND LIST
	SKIPN	TAC,(TAC)
	JRST	MTDCN2

IFE FTEXPG,<	ADD	TAC,MTPROG	;THE OLD WAY TO RELOCATE!
		MOVEM	TAC,DCWRD	;STORE NEW IOWD >

IFN FTEXPG,<
	MOVEM	TAC1,MTTAC1
	ADDI	TAC,1			;FIRST CORE ADDRESS
	MOVEM	TAC,DCWRD		;SAVE BLKI/O POINTER+1
	LDB	TAC,[POINT 9,DCWRD,26]	;TAC←PAGE NUMBER OF FIRST WORD
	MOVEI	TAC1,MTCEXP		;NUMBER OF FIRST EXEC PAGE FOR MTC
	DPB	TAC1,[POINT 9,DCWRD,26]	;STORE EXEC PAGE NUMBER INSTEAD
	SOS	DCWRD			;RE-CONVERT TO IOWD FORMAT
	ADD	TAC,MTCMAP		;POINTER TO USER'S PAGE MAP ENTRY
	MOVE	TAC1,(TAC)
	MOVEM	TAC1,EXPGT+MTCEXP	;MAKE EXEC MAP POINT TO USER'S PAGES
	MOVE	TAC1,1(TAC)
	MOVEM	TAC1,EXPGT+MTCEXP+1
NOKL10,<	CONO	PAG,1		>;NOKL10
IFKL10,<	CONO	KLPAG,@KLPCON	>;IFKL10
	MOVE	TAC1,MTTAC1
>;IFN FTEXPG

	JRST	MTDCN3

MTDCN2:	CONO	PI,DCTOFF	;SHUT OFF DC CHANNEL
	CONSZ	DC,10000	;DATA MISSED?
	SETOM	MISSED		;YES. OOPS
MTDCN3:	MOVE	TAC,MTTAC
	JEN	@MTDCND		;DISMISS INTERRUPT.
;LOW PRIORITY (CH4) INTERRUPTS FROM MTC COME HERE
↑MTCINT:JSR	MTCSAV			;SAVE AC'S
	HRRZ	DDB,MTDEV		;SET UP DDB POINTER
	LDB	J,PJOBN			;JOB NUMBER
	MOVE	IOS,DEVIOS(DDB)

;ALL I-LEVEL DISPATCHES BETWEEN MTXNC AND MTFIN ARE FOR NON-DATA OPERATIONS

	HRRZ	TAC,MTIDSP		;GET THE DISPATCH ADDRESS
	CAIL	TAC,MTXNC
	CAILE	TAC,MTFIN
	PUSHJ	P,MAPSET		;DATA XFER OP  SETUP MAP.
	JRST	@MTIDSP			;DISPATCH TO WHOMEVER

;HERE ON FIRST INTERRUPT FROM DATA TRANSFER OPERATION (XNC)
MTXNC:	MOVEI	TAC,ERF		;ENABLE SOFTWARE FOR ERF - END OF RECORD
	HRRM	TAC,MTCCON
	MOVEI	TAC,MTEOR	;SET DISPATCH ADDRESS TO MTEOR
	MOVEM	TAC,MTIDSP
	CONO	MTS,ERF		;ENABLE HARDWARE FOR ERF
	POPJ	P,		;DISMISS INTERRUPT

;MTNIO1, MTNIO2, MTREWW, ETCHK

;HERE ON XNC INTERRUPT FROM NON-DATA TRANSFER.
MTNIO2:	PUSHJ	P,MTERST	;RETURN WHEN ICR
	HLRZ	TAC,MTDEV	;COMMAND
	ANDI	TAC,17B27
	CAIE	TAC,6B27	;SPACING ONE RECORD?
	JRST	MTFIN		;NO.
	CONSZ	MTS,EFF		;EOF?
	TDO	IOS,[IOSEOF,,IODEND]	;SET IOS BITS TO SHOW END OF FILE
MTFIN:	TLZE	IOS,IOW		;CLEAR WAIT
	PUSHJ	P,SETIOD
MTNIO0:	PUSHJ	P,DETMDC	;DETACH MTC (IF HASMT SET) AND DC (IF IODT)
	PUSHJ	P,ETCHK		;CHECK FOR END OF TAPE
	PUSHJ	P,CLRACT	;RESTORE BITS,CLEAR IOACT
MTNIO1:	CONO	MTS,0		;CLEAR MAG TAPE ENABLES.
	CONO	MTC,MTCCHN	;CLEAR MAG TAPE CONTROL.
	HLLZS	MTCCON		;CLEAR THE INTERRUPT MASK BITS.
	SKIPL	MTREWN		;SOME OTHER UNIT REWINDING WITH A COMMAND HELD UP?
	JRST	MTREWW		;YES.  SEE IF IT HAS FINISHED REWINDING.
	POPJ	P,		;NO, DISMISS INTERRUPT


ETCHK:	CONSZ	MTS,TEP			;EOT SEEN?
	IORI	IOS,IOIMPM!IOTEND	;YES. SET FLAGS.
;TEP SHOULDN'T REALLY BE AN ERROR
	TDZ	IOS,[IOREW,,IOBOT]	;NO LONGER REWINDING
	CONSZ	MTS,RWD!TLP		;UNLESS
	TRO	IOS,IOBOT		;IS REALLY REWINDING
	POPJ	P,			;EXIT
;MTEOR - HERE ON ERF INTERRUPT FROM DATA TRANSFER OPERATION
MTEOR:	CONO	PI,DCTOFF	;TURN OFF DC IN CASE BLKI/BLKO DIDNT OVERFLOW
	CONSZ	DC,10000	;DATA MISS?
	SETOM	MISSED		;YES.
	CONSZ	MTS,EFF		;END-OF-FILE?
	SETOM	MTEOFF		;YES. SET FLAG
	SKIPE	@MTBLKP		;DID WE EXHAUST ALL THE IOWDS?
	TLNN	IOS,IO		;NO, NOT EXHAUSTED.  SKIP IF OUTPUT
	JRST	MTEOR0		;INPUT OR ALL IOWDS WERE EXHAUSTED.
	SETOM	MISSED		;SET DATA MISSED. - OUTPUT FAILED TO EXHAUST IOWDS
	JRST	MTEOR2		;ERROR.

MTEOR0:	CONSO	DC,160000	;DATA REMAINING IN DC?
	JRST	MTEOR1		;NO.
	TLNN	IOS,IO		;OUTPUT?
	SKIPE	MISSED		;NO.  DATA MISSED?
	JRST	MTEOR2		;YES (OUTPUT OR DATA MISSED).  ERROR.
	CONI	DC,TAC1		;FETCH DC STATUS BITS
	LSH	TAC1,-15	;SHIFT CHARACTER COUNT TO LSBITS
	IMULI	TAC1,-6		;-NO OF BITS TOO FAR RIGHT
	CONO	DC,@MDCSAV	;?? IF DON SAYS SO, WELL, OK (JUST)
	DATAI	DC,TAC		;FETCH LAST PART-WORD OF DATA
	LSH	TAC,44(TAC1)	;SHIFT LAST CHARACTERS TO LEFT END
	SKIPG	ITEM,DCWRD	;GET THE IOWD FOR INPUTTING LAST ITEM
	JRST	MTEORX		;IS ALREADY OK.
	SKIPN	@MTBLKP		;ARE WE AT THE END OF IOWD LIST YET?
	JRST	MTEOR1		;YES.  CAN'T DO ANY MORE.
	AOS	ITEM,MTBLKP	;GET NEXT IOWD.
	SKIPN	ITEM,(ITEM)
	JRST	MTEOR1

IFE FTEXPG,<	ADD	ITEM,MTPROG	;OLD WAY TO RELOCATE THE IOWD >

IFN FTEXPG,<
	ADDI	ITEM,1			;FIRST CORE ADDRESS
	LDB	AC2,[POINT 9,ITEM,26]	;AC2←PAGE NUMBER OF FIRST WORD
	MOVEI	AC3,MTCEXP		;NUMBER OF FIRST EXEC PAGE FOR MTC
	DPB	AC3,[POINT 9,ITEM,26]	;STORE EXEC PAGE NUMBER INSTEAD
	SUBI	ITEM,1			;RE-CONVERT TO IOWD FORMAT
	ADD	AC2,MTCMAP		;POINTER TO USER'S PAGE MAP ENTRY
	MOVE	AC3,(AC2)
	MOVEM	AC3,EXPGT+MTCEXP	;MAKE EXEC MAP POINT TO USER'S PAGES
NOKL10,<	CONO	PAG,1		>;NOKL10
IFKL10,<	CONO	KLPAG,@KLPCON	>;IFKL10
>;IFN FTEXPG


MTEORX:	ADD	ITEM,[1,,1]		;BUMP DATA POINTER
	MOVEM	TAC,(ITEM)		;STORE LAST WORD
	MOVEM	ITEM,DCWRD		;LET USER SEE LAST WORD.
	CONO	DC,0			;SHUT DOWN DC.

MTEOR1:	CONSZ	MTS,LPE!PER!ILC!MIS	;IF END OF RECORD, CHECK ERROR FLAGS
MTEOR2:	SKIPE	MTEOFF			;ERRORS.  BUT IS THERE END-OF-FILE?
	JRST	MTPDUN			;END OF FILE OR THERE'S NO ERROR.
MTERR:	MOVEI	ITEM,0
	CONSZ	MTS,LPE		;LONGITUDINAL PARITY ERROR?
	TLO	ITEM,1000	;YES, COUNT IN QUARTER 1
	CONSZ	MTS,PER		;LATERAL PARITY ERROR?
	TLO	ITEM,1		;YES, COUNT IN QUARTER 2
	CONSZ	MTS,ILC		;ILLEGAL OP?
	TRO	ITEM,1000	;YES, COUNT IN QUARTER 3
	SKIPE	MISSED		;DATA MISSED?
	TRO	ITEM,1		;YES, COUNT IN QUARTER 4
	ADDM	ITEM,MTCENT(DDB)	;ADD TO ERROR COUNTS FOR THIS DRIVE
	TRNE	IOS,IONRCK	;DOES USER WANT TO SUPPRESS ERROR HANDLING?
	JRST	MTERR4		;YES, GIVE HIM HIS ERROR BITS
	PUSHJ	P,MTERST	;RETURN ON ICR
	TLNE	IOS,IO		;READING OR WRITING?
	JRST	MTERR1		;WRITING.  WRITE BLANK TAPE OVER ERROR RECORD.
	AOSL	MTERCN		;TRIED ENOUGH TIMES YET?
	JRST	MTERR4		;YES. GIVE ERROR TO USER.
	TLC	IOS,ERSLIC!IOSLIC  ;COMPLEMENT STATE OF SLICE LEVEL EACH TIME
	JRST	MTERR2		;READING.  GO BACKSPACE TAPE AND RETRY.

MTERR1:	CONSZ	MTS,TEP		;WRITING.  TAPE AT END POINT YET?
	JRST	MTEND1		;YES.  GIVE UP. (EXIT GRACEFULLY?)
MTERR2:	HLRZ	TAC,MTDEV	;GET THE COMMAND.
	ANDCMI	TAC,17B27	;MASK OUT ALL FUNCTION BITS
	MOVEI	TAC,7B27(TAC)	;SET FUNCTION TO BSP
	PUSHJ	P,MTXCT		;INITIATE THE OPERATION
	PUSHJ	P,MTERST	;AND WAIT UNTIL BSR FINISHES.
	TLNN	IOS,IO		;WRITING?
	JRST	MTERR3		;NO. READING.
	HLRZ	TAC,MTDEV	;GET BACK COMMAND
	ANDCMI	TAC,17B27
	MOVEI	TAC,13B27(TAC)	;WRITE 3" OF BLANK TAPE
	PUSHJ	P,MTXCT		;INITIATE OPERATION
	PUSHJ	P,MTERST	;WAIT FOR WRITE BLANK TAPE TO COMPLETE.
MTERR3:	LDB	TAC,PIOMOD	;RE-ISSUE COMMAND THAT FAILED.  GET MODE.
	CAIL	TAC,DR		;DUMP MODE?
	JRST	MDRTRY		;YES.
	TLNE	IOS,IO		;INPUT OR OUTPUT?
	JRST	MTOUT1		;OUTPUT
	JRST	MTIN1		;INPUT

;HERE AFTER TOO MANY READ RETRIES.  ASSUME ERROR IS PERMANENT.
MTERR4:	CONSO	MTS,ILC!MIS	;SET IODERR IF ILLEG OR MISSED CHAR FLAGS
	SKIPE	MISSED		;SET IODERR IF DATA MISSED
	TRO	IOS,IODERR
	CONSZ	MTS,LPE!PER	;SET IODTER IF LONG OR LAT PARITY
	TRO	IOS,IODTER	;SET FLAG, SIMULATE BEING SUCCESSFULLY DONE.
;HERE IF SUCCESSFULLY DONE (OR AFTER TOO MANY RETIRES).  DO NEXT RECORD.
MTPDUN:	AOS	MTCBKN(DDB)	;SUCCESSFULLY DONE.  COUNT OPS DONE BY THIS DRIVE
	LDB	TAC,PIOMOD
	CAIL	TAC,DR
	JRST	DMPDUN		;DUMP
	TLNE	IOS,IO
	JRST	MTNOTI		;WRITING
	SKIPE	MTEOFF		;NOT EOF?
	JRST	MTEOF

IFE FTEXPG,<	HRRZ	TAC1,DCWRD	;TAC1←FINISHING ADDRESS
		SUB	TAC1,MTDCCN	;TAC1←FINISH-(START-1) = WORD COUNT
>;IFE FTEXPG

IFN FTEXPG,<
	HRRZ	TAC1,DCWRD		;TAC1←LAST WORD WRITTEN, IN EXEC SPACE
	SUBI	TAC1,<MTCEXP⊗=9>	;TAC1←LAST WORD WRITTEN RELATIVE TO 2 PAGES
	HRRZ	TAC,@MTBLKP		;TAC←FIRST WORD MOVED IN THIS XFER-1
	ADDI	TAC,1			;TAC←USER'S ADDRESS OF FIRST WORD WRITTEN
	TRZ	TAC,777			;TAC←FIRST ADDR OF FIRST PAGE WRITTEN INTO
	ADD	TAC1,TAC		;TAC1←USER'S ADDR OF LAST WORD WRITTEN
	HRRZ	TAC,MTBLK		;TAC←ADDR OF FIRST WORD WRITTEN-1
	SUB	TAC1,TAC		;TAC1←WC
>;IFN FTEXPG

	HRRZ	TAC,DEVIAD(DDB)	;BUFFER ADDRESS
	JUMPE	TAC,MTEND1	;JUMP IF RELEASE HAS WIPED OUT BUFFERS
	XCTR	XRW,[HRRM TAC1,1(TAC)]	;STORE WORD COUNT IN INPUT BUFFER.
	PUSHJ	P,ADVBFF
	JRST	MTEND1		;NEXT BUFFER FULL
	JRST	MTCONN		;CONTINUE MODE

MTNOTI:	PUSHJ	P,ADVBFE	;WRITING
	JRST	MTEND1
MTCONN:	CONSZ	MTS,TEP!BCT	;END OF TAPE OR IN LOCAL?
	JRST	MTEND1		;STOP TAPE
	CONO	DC,0		;CLEAR DATA CONTROL
	TLZE	IOS,IOW
	PUSHJ	P,SETIOD
	MOVEM	IOS,DEVIOS(DDB)
	TLNN	IOS,IO		;INPUT OR OUTPUT?
	JRST	MTIN0		;CALL INPUT SUBROUTINE
	JRST	MTOUT0		;CALL OUTPUT SUBROUTINE

MTEOF:	TLO	IOS,IOEND	;EOF SEEN DURING LAST LAST RECORD
	SETZM	MTEOFF		;CLEAR EOF FLAG
;DUMP MODE LIST EXHAUSTED, OR NO FREE BUFFERS, OR END OF FILE SEEN.
MTEND1:	CONO	DC,0		;TURN OFF DATA CONTROL
	CONO	PI,DCTOFF
	PUSHJ	P,DETDC		;DETACH DC (IF ASSIGNED)
	PUSHJ	P,ETCHK		;CHECK FOR END OF TAPE (FOR DUMP MODE OUT)
	PUSHJ	P,CLRACT	;CLEAR IOACT, STORE IOS
	HRRZM	DDB,MTDEV	;STORE DDB ADDRESS (DUMP MODE)
	PUSH	P,[MTFIN]	;SET NEXT DISPATCH ADDRESS TO MTFIN
MTERST:	POP	P,MTIDSP	;STORE RETURN ADDRESS.
	MOVEI	TAC,ICR		;RETURN ON ICR
	HRRM	TAC,MTCCON
	CONO	MTS,ICR		;ENABLE HARDWARE FOR ICR
	POPJ	P,		;DISMISS INTERRUPT
;DUMP MODE IO

MTDMPI:	PUSHJ	P,COMCHK		;INPUT UUO. CHECK COMMAND LIST.
	JRST	ADRERR
	PUSHJ	P,MTCHEK
	TLZ	IOS,IO			;READING
	TRNE	IOS,IODEND		;END-OF-FILE ALREADY?
	JRST	MTEND1			;YES. GIVE BACK MAG TAPE.
	JRST	MTDMP0			;SETUP TAC AND DO IT

MTDMPO:	PUSHJ	P,COMCHK		;OUTPUT UUO.  CHECK COMMAND LIST
	JRST	ADRERR
	PUSHJ	P,MTCHEK		;IS SYSTEM AVAILABLE
	TLO	IOS,IO			;SET WRITING.
	CONSZ	MTS,TWL			;TAPE WRITE LOCKED?
	JRST	MTOUTE			;YES. -- LOSE
MTDMP0:	HRRZ	TAC,UUO			;COMMAND LIST POINTER
	PUSH	P,[WAIT1]		;SET RETURN ADDRESS FROM MTINDC
MTDMP1:	LDB	J,PJOBN			;(HERE IN CH4 FOR NEXT COMMAND)
	HLRZ	DAT,JBTPAG(J)
	LSH	DAT,=9			;DAT←SIZE OF LOWER 
	CAIG	DAT,(TAC)		;CHECK ADDRESS OF NEXT COMMAND WORD.
	JRST	MTDMP2			;IT IS NOT LEGAL.
	HRRZM	TAC,MTCMDP		;SAVE COMMAND POINTER
	XCTR	XR,[SKIPN TAC,(TAC)]	;PICKUP COMMAND WORD
	JRST	MTEND1			;ZERO STOPS LIST
	TLNN	TAC,-1			;ZERO IN LEFT HALF IS A JUMP
	JRST	MTDMP1			;CHANGE COMMAND SEQUENCE (USE RIGHT HALF)
;INPUT MAY CLOBBER COMMAND LIST, SO CHECK EACH IOWD AT I-LEVEL.
	HLROM	TAC,SVCNTR		;SAVE NEGATIVE WORD COUNT COUNTER
	MOVEI	TAC,(TAC)		;GET ADDRESS PART ONLY
	MOVEI	DAT,JOBPFI		;USER'S LOWEST LEGAL IO ADDRESS.
	HLL	DAT,UUOPC(J)		;USER OR EXEC OPERATION?
	TLNN	DAT,USRMOD		;SKIP IF USER OP
	MOVEI	DAT,JOBSAV		;MONITOR GETS TO DO IO AT LOWER ADDRESSES.
	CAIGE	TAC,(DAT)		;IS THIS ADDRESS BELOW PROTECTED PART?
	JRST	MTDMP2			;NO. LOSE.
	SUB	TAC,SVCNTR		;CALCULATE ENDING ADDRESS
	HLRZ	DAT,JBTPAG(J)
	LSH	DAT,=9			;DAT←SIZE OF LOWER
	CAIL	TAC,(DAT)		;YES. LESS THAN END?
	JRST	MTDMP2			;NO. LOSE.
	MOVNI	TAC,MTREDO		;INITIALIZE RETRY COUNT FOR THIS RECORD.
	MOVEM	TAC,MTERCN
	TLZE	IOS,ERSLIC		;CLEAR SLICE LEVEL SET VIA ERROR RECOVERY
	TLC	IOS,IOSLIC		;IF ERSLIC WAS SET, COMPLEMENT IOSLIC
	XCTR	XR,[MOVE TAC,@MTCMDP]	;GET IOWD. 
	MOVEM	TAC,MTWCMA		;SAVE IN CASE OF SUBSEQUENT RETRY
;HERE IN CH4 IF THE PREVIOUS RECORD FAILED. RETRY OPERATION.
MDRTRY:	MOVE	TAC,MTWCMA		;GET OLD WCMA
;GO SETUP TAC1 AND ITEM.  CALL MTINDC. IF CALLED FROM UUO THEN RETURN THRU WAIT1
	TLNN	IOS,IO
	JRST	MDRT1			;READ
	JRST	MDWT1			;WRITE

;DUMP MODE ADDRESS ERROR.
MTDMP2:	PUSHJ	P,MTEND1		;STOP THE TAPE AS IF END OF COMMAND LIST
	JRST	ADRERR			;MAKE A LOSE MESSAGE


;HERE IN CH4 TO CONTINUE DUMP MODE IO AFTER A SUCCESSFUL RECORD
DMPDUN:	AOS	TAC,MTCMDP		;ADVANCE TO NEXT IOWD
	TLNE	IOS,IO			;IN OR OUT?
	JRST	DMPDU1			;OUT
	SKIPE	MTEOFF			;END OF FILE?
	JRST	MTEOF			;YES. SET IODEND AND STOP
	PUSHJ	P,ETCHK			;CHECK FOR END OF TAPE
	JRST	MTDMP1			;START NEXT READ OR WRITE

DMPDU1:	CONSZ	MTS,TEP			;SKIP UNLESS END OF TAPE
	JRST	MTEND1			;END OF TAPE.  STOP OUTPUT
	PUSHJ	P,ETCHK			;CHECK FOR END OF TAPE
	JRST	MTDMP1			;START NEXT READ OR WRITE

	BEND	MTCSER